Chapter Contents Previous Next
 Nonlinear Optimization Examples

## Example 11.3: Compartmental Analysis

### Numerical Considerations

An important class of nonlinear models involves a dynamic description of the response rather than an explicit description. These models arise often in chemical kinetics, pharmacokinetics, and ecological compartmental modeling. Two examples are presented in this section. Refer to Bates and Watts (1988) for a more general introduction to the topic.

In this class of problems, function evaluations, as well as gradient evaluations, are not done in full precision. Evaluating a function involves the numerical solution of a differential equation with some prescribed precision. Therefore, two choices exist for evaluating first- and second-order derivatives:

• differential equation approach
• finite difference approach
In the differential equation approach, the components of the Hessian and the gradient are written as a solution of a system of differential equations that can be solved simultaneously with the original system. However, the size of a system of differential equations, n, would suddenly increase to n2+2n. This huge increase makes the finite difference approach an easier one.

With the finite difference approach, a very delicate balance of all the precision requirements of every routine must exist. In the examples that follow, notice the relative levels of precision that are imposed on different modules. Since finite differences are used to compute the first- and second-order derivatives, it is incorrect to set the precision of the ODE solver at a coarse level because that would render the numerical estimation finite difference worthless.

A coarse computation of the solution of the differential equation cannot be accompanied by very fine computation of the finite difference estimates of the gradient and the Hessian. That is, you cannot set the precision of the differential equation solver to be 1E-4 and perform the finite difference estimation with a precision of 1E-10. In addition, this precision must be well-balanced with the termination criteria imposed on the optimization process.

In general, if the precision of the function evaluation is , the gradient should be computed by finite differences , and the Hessian should be computed with finite differences .*

### Diffusion of Tetracycline

Consider the concentration of tetracycline hydrochloride in blood serum. The tetracycline is administered to a subject orally, and the concentration of the tetracycline in the serum is measured. The biological system to be modeled will consist of two compartments: a gut compartment in which tetracycline is injected and a blood compartment that absorbs the tetracycline from the gut compartment for delivery to the body. Let and be the concentrations at time t in the gut and the serum, respectively. Let and be the transfer parameters. The model is depicted as follows.

The rates of flow of the drug are described by the following pair of ordinary differential equations:

The initial concentration of the tetracycline in the gut is unknown, and while the concentration in the blood can be measured at all times, initially it is assumed to be zero. Therefore, for the differential equation, the initial conditions will be given by

Also, a nonnegativity constraint is imposed on the parameters , , and , although for numerical purposes, you may need to use a small value instead of zero for these bounds (such as 1E-7).

Suppose yi is the observed serum concentration at time ti. The parameters are estimated by minimizing the sum of squares of the differences between the observed and predicted serum concentrations:

The following IML program illustrates how to combine the NLPDD subroutine and the ODE subroutine to estimate the parameters of this model. The input data are the measurement time and the concentration of the tetracycline in the blood. For more information on the ODE call, see the "ODE Call" section.

   data tetra;
input t c @@;
datalines;
1 0.7   2 1.2   3 1.4   4 1.4   6 1.1
8 0.8  10 0.6  12 0.5  16 0.3
;

proc iml;
use tetra;
start f(theta) global(thmtrx,t,h,tetra,eps);
thmtrx = ( -theta[1] || 0 )     //
(  theta[1] || -theta[2] );
c = theta[3]//0 ;
t = 0 // tetra[,1];
call ode( r1, "der",c , t, h) j="jac" eps=eps;
f = ssq((r1[2,])-tetra[,2]);
return(f);
finish;

start der(t,x) global(thmtrx);
y = thmtrx*x;
return(y);
finish;

start jac(t,x) global(thmtrx);
y = thmtrx;
return(y);
finish;

h      = {1.e-14 1. 1.e-5};
opt    = {0 2 0 1 };
tc     = repeat(.,1,12);
tc[1]  = 100;
tc[7]  = 1.e-8;
par    = { 1.e-13 . 1.e-10 . . . . };
con    = j(1,3,0.);
itheta = { .1  .3  10};
eps    = 1.e-11;

call nlpdd(rc,rx,"f",itheta) blc=con opt=opt tc=tc par=par;


The output from the optimization process is shown in Output 11.3.1.

Output 11.3.1: Printed Output for Tetracycline Diffusion Problem

 Optimization Start Parameter Estimates N Parameter Estimate GradientObjectiveFunction LowerBoundConstraint UpperBoundConstraint 1 X1 0.100000 76.587053 0 . 2 X2 0.300000 -48.230224 0 . 3 X3 10.000000 1.672495 0 .

 Value of Objective Function = 4.1469872307

 Double Dogleg Optimization

 Dual Broyden - Fletcher - Goldfarb - Shanno Update (DBFGS)

 Without Parameter Scaling

 Parameter Estimates 3 Lower Bounds 3 Upper Bounds 0

 Optimization Start Active Constraints 0 Objective Function 4.1469872307 Max Abs Gradient Element 76.587052967 Radius 1

 Iteration Restarts FunctionCalls ActiveConstraints ObjectiveFunction ObjectiveFunctionChange Max AbsGradientElement Lambda Slope ofSearchDirection 1 0 5 0 3.12254 1.0244 124.4 67.120 -8.030 2 0 6 0 0.89497 2.2276 14.1533 1.885 -5.025 3 0 7 0 0.32313 0.5718 3.7141 1.184 -0.785 . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . 32 0 45 0 0.03565 2.05E-10 0.000801 3.915 -3E-8

Output 11.3.1: (continued)

 Optimization Results Iterations 32 Function Calls 46 Gradient Calls 34 Active Constraints 0 Objective Function 0.0356522978 Max Abs Gradient Element 0.0008005458 Slope of Search Direction -2.999826E-8 Radius 1

 FCONV convergence criterion satisfied.

 Optimization Results Parameter Estimates N Parameter Estimate GradientObjectiveFunction 1 X1 0.181807 0.000388 2 X2 0.437717 0.000801 3 X3 6.048279 0.000239

 Value of Objective Function = 0.0356522978

The differential equation model is linear, and in fact, it can be solved using an eigenvalue decomposition (this is not always feasible without complex arithmetic). Alternately, the availability and the simplicity of the closed form representation of the solution enables you to replace the solution produced by the ODE routine with the simpler and faster analytical solution. Closed forms are not expected to be easily available for nonlinear systems of differential equations, which is why the preceding solution was introduced.

The closed form of the solution requires a change to the function f(·). The functions needed as arguments of the ODE routine, namely the der and jac modules, can be removed.

   start f(th) global(theta,tetra);
theta = th;
vv    = v(tetra[,1]);
error = ssq(vv-tetra[,2]);
return(error);
finish;

start v(t) global(theta);
v = theta[3]*theta[1]/(theta[2]-theta[1])*
(exp(-theta[1]*t)-exp(-theta[2]*t));
return(v);
finish;

call nlpdd(rc,rx,"f",itheta) blc=con opt=opt tc=tc par=par;


The parameter estimates, which are shown in Output 11.3.2, are close to those obtained by the first solution.

Output 11.3.2: Second Set of Parameter Estimates for Tetracycline Diffusion

 Optimization Results Parameter Estimates N Parameter Estimate GradientObjectiveFunction 1 X1 0.183025 -0.000003196 2 X2 0.434482 0.000002274 3 X3 5.995241 -0.000001035

 Value of Objective Function = 0.0356467763

Because of the nature of the closed form of the solution, you may want to add an additional constraint to guarantee that at any time during the optimization. This will prevent a possible division by 0 or a value near 0 in the execution of the v(·) function. For example, you might add the constraint

### Chemical Kinetics of Pyrolysis of Oil Shale

Pyrolysis is a chemical change effected by the action of heat, and this example considers the pyrolysis of oil shale described in Ziegel and Gorman (1980). Oil shale contains organic material that is bonded to the rock. To extract oil from the rock, heat is applied, and the organic material is decomposed into oil, bitumen, and other by-products. The model is given by
with the initial conditions
A dead time is assumed to exist in the process. That is, no change occurs up to time . This is controlled by the indicator function , which is given by
where .Only one of the cases in Ziegel and Gorman (1980) is analyzed in this report, but the others can be handled in a similar manner. The following IML program illustrates how to combine the NLPQN subroutine and the ODE subroutine to estimate the parameters in this model:

   data oil ( drop=temp);
input temp time bitumen oil;
datalines;
673     5      0.      0.
673     7      2.2     0.
673    10     11.5     0.7
673    15     13.7     7.2
673    20     15.1    11.5
673    25     17.3    15.8
673    30     17.3    20.9
673    40     20.1    26.6
673    50     20.1    32.4
673    60     22.3    38.1
673    80     20.9    43.2
673   100     11.5    49.6
673   120      6.5    51.8
673   150      3.6    54.7
;

proc iml;
use oil;

/****************************************************************/
/* The INS function inserts a value given by FROM into a vector */
/* given by INTO, sorts the result, and posts the global matrix */
/* that can be used to delete the effects of the point FROM.    */
/****************************************************************/
start ins(from,into) global(permm);
in    =  into // from;
x     =  i(nrow(in));
permm = inv(x[rank(in),]);
return(permm*in);
finish;

start der(t,x) global(thmtrx,thet);
y     = thmtrx*x;
if ( t <= thet[5] )  then y = 0*y;
return(y);
finish;

start jac(t,x) global(thmtrx,thet);
y     = thmtrx;
if ( t <= thet[5] )  then y = 0*y;
return(y);
finish;

start f(theta) global(thmtrx,thet,time,h,a,eps,permm);
thet = theta;
thmtrx = (-(theta[1]+theta[4]) ||         0            || 0 )//
(theta[1]             || -(theta[2]+theta[3]) || 0 )//
(theta[4]             || theta[2]             || 0 );
t = ins( theta[5],time);
c = { 100, 0, 0};
call ode( r1, "der",c , t , h) j="jac" eps=eps;

/* send the intermediate value to the last column */
r = (c ||r1) * permm;
m = r[2:3,(2:nrow(time))];
mm = m- a[,2:3];
call qr(q,r,piv,lindep,mm);
v = det(r);
return(abs(v));
finish;

opt = {0 2 0 1 };
tc = repeat(.,1,12);
tc[1] = 100;
tc[7] = 1.e-7;
par = { 1.e-13 . 1.e-10 . . . .};
con = j(1,5,0.);
h = {1.e-14 1. 1.e-5};
time = (0 // a[,1]);
eps = 1.e-5;
itheta = { 1.e-3 1.e-3 1.e-3 1.e-3 1.};

call nlpqn(rc,rx,"f",itheta)  blc=con opt=opt tc=tc par=par;


The parameter estimates are shown in Output 11.3.3.

Output 11.3.3: Parameter Estimates for Oil Shale Pyrolysis

 Optimization Results Parameter Estimates N Parameter Estimate GradientObjectiveFunction 1 X1 0.014076 110848 2 X2 0.012477 66427 3 X3 0.019148 40144 4 X4 0.006543 -13281 5 X5 2.4404807E-9 64209

 Value of Objective Function = 106.64284257

Again, compare the solution using the approximation produced by the ODE subroutine to the solution obtained through the closed form of the given differential equation. Impose the following additional constraint to avoid a possible division by 0 when evaluating the function:
The closed form of the solution requires a change in the function f(·). The functions needed as arguments of the ODE routine, namely the der and jac modules, can be removed.

   start f(thet) global(time,a);
do i = 1 to nrow(time);
t   = time[i];
v1  = 100;
if ( t >= thet[5] ) then
v1 = 100*ev(t,thet[1],thet[4],thet[5]);
v2 = 0;
if ( t >= thet[5] ) then
v2 = 100*thet[1]/(thet[2]+thet[3]-thet[1]-thet[4])*
(ev(t,thet[1],thet[4],thet[5])-
ev(t,thet[2],thet[3],thet[5]));
v3 = 0;
if ( t >= thet[5] ) then
v3  = 100*thet[4]/(thet[1]+thet[4])*
(1. - ev(t,thet[1],thet[4],thet[5])) +
100*thet[1]*thet[2]/(thet[2]+thet[3]-thet[1]-thet[4])*(
(1.-ev(t,thet[1],thet[4],thet[5]))/(thet[1]+thet[4]) -
(1.-ev(t,thet[2],thet[3],thet[5]))/(thet[2]+thet[3])    );
y = y // (v1 || v2 || v3);
end;
mm = y[,2:3]-a[,2:3];
call qr(q,r,piv,lindep,mm);
v = det(r);
return(abs(v));
finish;

start ev(t,a,b,c);
return(exp(-(a+b)*(t-c)));
finish;

con     = { 0.  0.  0.  0.   .   .  . ,
.   .   .   .   .    . . ,
-1   1   1  -1   .   1  1.e-7 };
time    =  a[,1];
par     = { 1.e-13 . 1.e-10 . . . .};
itheta  = { 1.e-3 1.e-3 1.e-2 1.e-3 1.};

call nlpqn(rc,rx,"f",itheta)  blc=con opt=opt tc=tc par=par;


The parameter estimates are shown in Output 11.3.4.

Output 11.3.4: Second Set of Parameter Estimates for Oil Shale Pyrolysis

 Optimization Results Parameter Estimates N Parameter Estimate GradientObjectiveFunction 1 X1 0.017178 -0.005291 2 X2 0.008912 0.002413 3 X3 0.020007 -0.000520 4 X4 0.010494 -0.002890 5 X5 7.771534 0.000003217

 Value of Objective Function = 20.689350642

 Chapter Contents Previous Next Top