Chapter Contents Previous Next
 Details of the FACTEX Procedure

## Example 15.6: Two-Level Design with Design Replication and Point Replication

 See FACTEX12 in the SAS/QC Sample Library

You can replicate a design to obtain an independent estimate of experimental error or to estimate effects more precisely. There are two ways you can replicate a design using the FACTEX procedure: you can replicate the entire design with the DESIGNREP= option, or you can replicate each point in the design with the POINTREP= option. The following example illustrates the difference.

A process engineer is conducting an experiment to study the shrinkage of an injection-molded plastic component. The engineer chooses to determine the effect of the following four factors, each at two levels: holding pressure (PRESSURE), molding temperature (TEMP), cooling time (TIME), and injection velocity (VELOCITY).

The design used is a half-fraction of a 24 factorial design, denoted as 24-1IV. The following statements construct the design:

```   proc factex;
factors pressure temp time velocity;
size fraction=2;
model res=max;
output out=savunrep;
run;

proc print data=savunrep;
run;
```

The design, saved in the data set SAVUNREP, is shown in Output 15.6.1.

Output 15.6.1: Unreplicated Design

 Obs pressure temp time velocity 1 -1 -1 -1 -1 2 -1 -1 1 1 3 -1 1 -1 1 4 -1 1 1 -1 5 1 -1 -1 1 6 1 -1 1 -1 7 1 1 -1 -1 8 1 1 1 1

To obtain a more precise estimate of the experimental error, the engineer decides to replicate the entire design three times. The following statements generate a 24-1IV design with three replicates in 24 runs:

```   proc factex;
factors pressure temp time velocity;
size fraction=2;
model res=max;
output out=savedrep designrep=3;
run;

proc print data=savedrep;
run;
```

The design, saved in the data set SAVEDREP, is displayed in Output 15.6.2.

Output 15.6.2: Design Replication

 Obs pressure temp time velocity 1 -1 -1 -1 -1 2 -1 -1 1 1 3 -1 1 -1 1 4 -1 1 1 -1 5 1 -1 -1 1 6 1 -1 1 -1 7 1 1 -1 -1 8 1 1 1 1 9 -1 -1 -1 -1 10 -1 -1 1 1 11 -1 1 -1 1 12 -1 1 1 -1 13 1 -1 -1 1 14 1 -1 1 -1 15 1 1 -1 -1 16 1 1 1 1 17 -1 -1 -1 -1 18 -1 -1 1 1 19 -1 1 -1 1 20 -1 1 1 -1 21 1 -1 -1 1 22 1 -1 1 -1 23 1 1 -1 -1 24 1 1 1 1

The first replicate comprises observations 1 to 8, the second replicate comprises observations 9 to 16, and the third replicate comprises observations 17 to 24.

Now, instead of replicating the entire design, suppose the engineer decides to replicate each run in the design three times. The following statements construct a 24-1IV design in 24 runs with point replication:

```   proc factex;
factors pressure temp time velocity;
size fraction=2;
model res=max;
output out=saveprep pointrep=3;
run;

proc print data=saveprep;
run;
```

The design, saved in the data set SAVEPREP, is displayed in Output 15.6.3. The first design point is replicated three times (observations 1 -3), the second design point is replicated three times (observations 4 -6), and so on.

Output 15.6.3: Point Replication

 Obs pressure temp time velocity 1 -1 -1 -1 -1 2 -1 -1 -1 -1 3 -1 -1 -1 -1 4 -1 -1 1 1 5 -1 -1 1 1 6 -1 -1 1 1 7 -1 1 -1 1 8 -1 1 -1 1 9 -1 1 -1 1 10 -1 1 1 -1 11 -1 1 1 -1 12 -1 1 1 -1 13 1 -1 -1 1 14 1 -1 -1 1 15 1 -1 -1 1 16 1 -1 1 -1 17 1 -1 1 -1 18 1 -1 1 -1 19 1 1 -1 -1 20 1 1 -1 -1 21 1 1 -1 -1 22 1 1 1 1 23 1 1 1 1 24 1 1 1 1

Note the difference in the arrangement of the designs created using design replication (Output 15.6.2) and point replication (Output 15.6.3). In design replication, the original design is replicated a specified number of times; but in point replication, each run in the original design is replicated a specified number of times. See "Replication" for more information on design replication.

 Chapter Contents Previous Next Top