Chapter Contents
Chapter Contents
Specialized Control Charts

Determining the Components of Variation

The standard Shewhart analysis assumes that sampling variation, also referred to as within-group variation, is the only source of variation. Writing xij for the j th measurement within the i th subgroup, you can express the model for the conventional \bar{X} and R chart as

 x_{ij} = \mu + \sigma_{W} \epsilon_{ij}
for i = 1, 2, ... , k and j = 1, 2, ... , n. The random variables \epsilon_{ij} are assumed to be independent with zero mean and unit variance, and \sigma^2_{W} is the within-subgroup variance. The parameter \mu denotes the process mean.

In a process such as film manufacturing, this model is not adequate because there is additional variation due to changes in temperature, pressure, raw material, and other factors. Instead, a useful model is

 x_{ij} = \mu + \sigma_{B} \omega_{i} + \sigma_{W} \epsilon_{ij}
where \sigma^2_{B} is the between-subgroup variance, the random variables \omega_{i} are independent with zero mean and unit variance, and the random variables \omega_{i} are independent of the random variables \epsilon_{ij}.*

To plot the subgroup averages \bar{x}_{i.} \equiv \sum \frac{x_{ij}}non a control chart, you need expressions for the expectation and variance of \bar{x}_{i.}. These are

 E (\bar{x}_{i.} ) & = & \mu \ {Var} (\bar{x}_{i.} ) & = & \sigma^2_{B} +
Thus, the central line should be located at \hat{\mu},and 3\sigma limits should be located at

 \hat{\mu} +- 3 \sqrt{ \hat{\sigma}^2_{B} +
 \frac{\hat{\sigma}^2_{W}}n }
where \hat{\sigma}^2_{B} and \hat{\sigma}^2_{W} denote estimates of the variance components. You can use a variety of SAS procedures for fitting linear models to estimate the variance components. The following statements show how this can be done with the MIXED procedure:
   proc mixed data=film;
      class sample;
      model testval = / s;
      random sample;
      make 'solutionf' out=sf;
      make 'covparms'  out=cp;
The results are shown in Figure 49.11. Note that the parameter estimates are \hat{\sigma}^2_B=19.25,\hat{\sigma}^2_W=39.68,and \hat{\mu}=88.90.

The Mixed Procedure

Covariance Parameter Estimates
Cov Parm Estimate
sample 19.2526
Residual 39.6825
Solution for Fixed Effects
Effect Estimate Standard Error DF t Value Pr > |t|
Intercept 88.8963 0.7250 55 122.61 <.0001
Figure 49.11: Partial Output from the MIXED Procedure

The following statements merge the output data sets from the MIXED procedure into a SAS data set named NEWLIM that contains the appropriately derived control limit parameters for the average test value:

   data cp;
      set cp sf;
      keep est;

   proc transpose data=cp out=newlim;

   data newlim;
      set newlim;
      drop _name_ _label_ col1-col3;
      length _var_ _subgrp_ _type_ $8;
      _var_    = 'testval';
      _subgrp_ = 'sample';
      _type_   = 'estimate';
      _limitn_ = 4;
      _mean_   = col3;
      _stddev_ = sqrt(4*col1 + col2);
Here, the variable _LIMITN_ is assigned the value of n, the variable _MEAN_ is assigned the value of \hat{\mu},and the variable _STDDEV_ is assigned the value of

 \hat{\sigma}\!_{{\scriptsize adj}} \equiv
 \sqrt{ 4 \hat{\sigma}^2_{B} + \hat{\sigma}^2_{W} }
In the following statements, the SHEWHART procedure reads these parameter estimates and displays the \bar{X}and R chart shown in Figure 49.12:
   symbol v=dot c=yellow;
   title 'Control Chart With Adjusted Limits';
   proc shewhart data=film limits=newlim;
      xrchart testval*sample / npanelpos = 60
                               cframe    = vigb
                               cinfill   = vlib
                               cconnect  = yellow;
The control limits for the \bar{X} chart are displayed as \hat{\mu} +- \frac{3}{\sqrt{n}} \hat{\sigma}\!_{{\scriptsize adj}}.Note that the chart in Figure 49.12 correctly indicates that the variation in the process is due to common causes.

You can use a similar set of statements to display the derived control limits in NEWLIM on an \bar{X}and R chart for the original data (including outliers), as shown in Figure 49.13.

A simple alternative to the chart in Figure 49.12 is an "individual measurements" chart for the subgroup means. The advantage of the variance components approach is that it yields separate estimates of the components due to lane and sample, as well as a number of hypothesis tests (these require assumptions of normality). In applying this method, however, you should be careful to use data that represent the process in a state of statistical control.

smultcp6.gif (7385 bytes)

Figure 49.12: \bar{X} and R Chart with Derived Control Limits

smultcp7.gif (7141 bytes)

Figure 49.13: \bar{X} and R Chart with Derived Control Limits for Raw Data

Chapter Contents
Chapter Contents

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.