Chapter Contents
Chapter Contents
Previous
Previous
Next
Next
The PLAN Procedure

Randomly Assigning Subjects to Treatments

You can use the PLAN procedure to design a completely randomized design. Suppose you have 12 experimental units, and want to assign one of two treatments to each unit. Use a DATA step to store the unrandomized design in a SAS data set, then call PROC PLAN to randomize it by specifying one RANDOM factor of 12 levels. The following statements produce Figure 50.3 and Figure 50.4:

   title 'Completely Randomized Design';
   /* The unrandomized design */
   data a;
      do unit=1 to 12;
         if (unit <= 6) then treat=1;
         else                treat=2;
         output;
      end;
   run;

   /* Randomize the design */
   proc plan seed=27371;
      factors unit=12;
      output data=a out=b;
   run;

   proc sort data=b;
      by unit;
   proc print;
   run;

Figure 50.3 shows that the 12 levels of the unit factor have been randomly reordered and then lists the new ordering.

Completely Randomized Design

The PLAN Procedure

Factor Select Levels Order
unit 12 12 Random

unit
8 5 1 4 6 2 12 7 3 9 10 11

Figure 50.3: A Completely Randomized Design for Two Treatments

After the data is sorted by the unit variable, the randomized design is displayed in Figure 50.4.

Completely Randomized Design

Obs unit treat
1 1 1
2 2 1
3 3 2
4 4 1
5 5 1
6 6 1
7 7 2
8 8 1
9 9 2
10 10 2
11 11 2
12 12 2

Figure 50.4: A Completely Randomized Design for Two Treatments

You can also generate the plan by using a TREATMENTS statement instead of a DATA step. The following statements generate the same plan.

   proc plan seed=27371;
      factors unit=12;
      treatments treat=12 cyclic (1 1 1 1 1 1 2 2 2 2 2 2);
      output out=b;
   run;

Chapter Contents
Chapter Contents
Previous
Previous
Next
Next
Top
Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.