PROBMC

PROBMC

Computes a probability or a quantile from various distributions for multiple comparisons of means, and returns a value

 Category: Probability

Syntax

 PROBMC(distribution, q, prob, df, nparms<, parameters>)

Arguments

distribution
is a character string that identifies the distribution. Valid distributions are

Distribution Argument
One-sided Dunnett
`'DUNNETT1'`
Two-sided Dunnett
`'DUNNETT2'`
Maximum Modulus
`'MAXMOD'`
Studentized Range
`'RANGE'`
Williams
`'WILLIAMS'`

q
is the quantile from the distribution.
 Restriction: Either q or prob can be specified, but not both.

prob
is the left probability from the distribution.
 Restriction: Either prob or q can be specified, but not both.

df
is the degrees of freedom.

Note:   A missing value is interpreted as an infinite value.

nparms
is the number of treatments.

Note:   For DUNNETT1 and DUNNETT2, the control group is not counted.

parameters
is an optional set of nparms parameters that must be specified to handle the case of unequal sample sizes. The meaning of parameters depends on the value of distribution. If parameters is not specified, equal sample sizes are assumed; this is usually the case for a null hypothesis.

The PROBMC function returns the probability or the quantile from various distributions with finite and infinite degrees of freedom for the the variance estimate.

The prob argument is the probability that the random variable is less than q. Therefore, p-values can be computed as 1- prob. For example, to compute the critical value for a 5% significance level, set prob= 0.95. The precision of the computed probability is O(10--8) (absolute error); the precision of computed quantile is O(10--5).

Note:   The studentized range is not computed for finite degrees of freedom and unequal sample sizes.

Note:   Williams' test is computed only for equal sample sizes.

Formulas and Parameters

The equations listed here define expressions used in equations that relate the probability, prob, and the quantile, q, for different distributions and different situations within each distribution. For these equations, let be the degrees of freedom, df.

The Studentized Range

• This case relates the probability, prob, and the quantile, q, for the equal case with finite degrees of freedom. No parameters are passed, the value of nparms is set to k, and the value of df is set to . The equation follows:

• This case relates the probability, prob, and the quantile, q, for the unequal case with infinite degrees of freedom. The parameters are 1, ..., k, the value of nparms is set to k, and the value of df is set to missing. The equation follows:

• This case relates the probability, prob, and the quantile, q, for the equal case with infinite degrees of freedom. No parameters are passed, the value of nparms is set to k, and the value of df is set to missing. The equation follows:

Williams' Test

PROBMC computes the probabilities or quantiles from the distribution defined in Williams (1971, 1972) (See References). It arises when you compare the dose treatment means with a control mean to determine the lowest effective dose of treatment.

Note:   Williams' Test is computed only for equal sample sizes.

Let X1, X2, ..., Xk be identical independent N(0,1) random variables. Let Yk denote their average given by

It is required to compute the distribution of

where
 Yk is as defined previously Z is a N(0,1) independent random variable S is such that ½S2 is a 2 variable with degrees of freedom.

As described in Williams (1971) (See References), the full computation is extremely lengthy and is carried out in three stages.

1. Compute the distribution of Yk. It is the fundamental (expensive) part of this operation and it can be used to find both the density and the probability of Yk. Let Ui be defined as

You can write a recursive expression for the probability of Yk > d, with d being any real number.

To compute this probability, start from a N(0,1) density function

and recursively compute the convolution

From this sequential convolution, it is possible to compute all the elements of the recursive equation for , shown previously.

2. Compute the distribution of Yk - Z. This involves another convolution to compute the probability

3. Compute the distribution of (Yk - Z)/S. This involves another convolution to compute the probability

The third stage is not needed when = ∞. Due to the complexity of the operations, this lengthy algorithm is replaced by a much faster one when k 15 for both finite and infinite degrees of freedom . For k 16, the lengthy computation is carried out. It is extremely expensive and very slow due to the complexity of the algorithm.

The MEANS statement in the GLM Procedure of SAS/STAT Software computes the following tests:

• Dunnett's one-sided test

• Dunnett's two-sided test

• Studentized Range.

Example 1: Using PROBMC to Compute Probabilities

```data probs;
array par{5};
par{1}=.5;
par{2}=.51;
par{3}=.55;
par{4}=.45;
par{5}=.2;
df=40;
q=1;
do test="dunnett1","dunnett2", "maxmod";
prob=probmc(test, q, ., df, 5, of par1-par5);
put test \$10. df q e18.13 prob e18.13;
end;
run; ```
Probabilities from PROBMC shows the results of this DATA step that are printed to the SAS log.

Probabilities from PROBMC
 ```DUNNETT1 40 1.00000000000E+00 4.82992188740E-01 DUNNETT2 40 1.00000000000E+00 1.64023099613E-01 MAXMOD 40 1.00000000000E+00 8.02784203408E-01```

Example 2: Comparing Means

This example shows how to compare group means to find where the significant differences lie. The data for this example is taken from a paper by Duncan (1955) (See References) and can also be found in Hochberg and Tamhane (1987) (See References). The group means are
 49.6 71.2 67.6 61.5 71.3 58.1 61
For this data, the mean square error is s2 = 79.64 (s = 8.924) with = 30.

```data duncan;
array tr{7}\$;
array mu{7};
n=7;
do i=1 to n;
input tr{i} \$1. mu{i};
end;
input df s alpha;
prob= 1-alpha;
/* compute the interval */
x = probmc("RANGE", ., prob, df, 7);
w = x * s / sqrt(6);
/* compare the means */
do i = 1 to n;
do j = i + 1 to n;
dmean = abs(mu{i} - mu{j});
if dmean >= w then do;
put tr{i} tr{j} dmean;
end;
end;
end;
datalines;
A 49.6
B 71.2
C 67.6
D 61.5
E 71.3
F 58.1
G 61.0
30 8.924 .05
;```
Group Differences shows the results of this DATA step that are printed to the SAS log.

Group Differences
 ```A B 21.6 A C 18 A E 21.7```

Example 3: Computing Confidence Intervals

This example shows how to compute 95% one-sided and two-sided confidence intervals of Dunnett's test. This example and the data come from Dunnett (1955) (See References) and can also be found in Hochberg and Tamhane (1987) (See References). The data are blood count measurements on three groups of animals. As shown in the following table, the third group serves as the control, while the first two groups were treated with different drugs. The numbers of animals in these three groups are unequal.

Treatment Group: Drug A Drug B Control

9.76 12.80 7.40

8.80 9.68 8.50

7.68 12.16 7.20

9.36 9.20 8.24

10.55 9.84

8.32
Group Mean 8.90 10.88 8.25
n 4 5 6

The mean square error s2 = 1.3805 (s = 1.175) with = 12.

```data a;
array drug{3}\$;
array count{3};
array mu{3};
array lambda{2};
array delta{2};
array left{2};
array right{2};

/* input the table */
do i = 1 to 3;
input drug{i} count{i} mu{i};
end;

/* input the alpha level,    */
/* the degrees of freedom,   */
/* and the mean square error */
input alpha df s;

/* from the sample size, */
/* compute the lambdas   */
do i = 1 to 2;
lambda{i} = sqrt(count{i}/
(count{i} + count{3}));
end;

/* run the one-sided Dunnett's test */
test="dunnett1";
x = probmc(test, ., 1 - alpha, df,
2, of lambda1-lambda2);
do i = 1 to 2;
delta{i} = x * s *
sqrt(1/count{i} + 1/count{3});
left{i} = mu{i} - mu{3} - delta{i};
end;
put test \$10. x left{1} left{2};

/* run the two-sided Dunnett's test */
test="dunnett2";
x = probmc(test, ., 1 - alpha, df,
2, of lambda1-lambda2);
do i=1 to 2;
delta{i} = x * s *
sqrt(1/count{i} + 1/count{3});
left{i} = mu{i} - mu{3} - delta{i};
right{i} = mu{i} - mu{3} + delta{i};
end;
put test \$10. left{1} right{1};
put test \$10. left{2} right{2};
datalines;
A 4 8.90
B 5 10.88
C 6 8.25
0.05 12 1.175
;```
Confidence Intervals shows the results of this DATA step that are printed to the SAS log.

Confidence Intervals
 ```DUNNETT1 2.1210786586 -0.958751705 1.1208571303 DUNNETT2 -1.256411895 2.5564118953 DUNNETT2 0.8416271203 4.4183728797```

Example 4: Computing Williams' Test

Treatment Mean
X0 10.4
X1 9.9
X2 10.0
X3 10.6
X4 11.4
X5 11.9
X6 11.7

The mean square, with (7 - 1)(8 - 1) = 42 degrees of freedom, is s2 = 1.16.

Determine the maximum likelihood estimates Mi through the averaging process.

• Because X0 > X1, form X0,1 = (X0 + X1)/2 = 10.15.

• Because X0,1 > X2, form X0,1,2 = (X0 + X1 + X2)/3 = (2X0,1 + X2)/3 = 10.1.

• X0,1,2 < X3 < X4 < X5

• Because X5 > X6, form X5,6 = (X5 + X6)/2 = 11.8.

Now the order restriction is satisfied.

The maximum likelihood estimates under the alternative hypothesis are
 M0 = M1 = M2 = X0,1,2 = 10.1 M3 = X3 = 10.6 M4 = X4 = 11.4 M5 = M6 = X5,6 = 11.8

Now compute , and the probability that corresponds to k = 6, = 42, and t = 2.60 is .9924467341, which shows strong evidence that there is a response to the substance. You can also compute the quantiles for the upper 5% and 1% tails, as shown in the following table.

SAS Statements Results
`prob=probmc("williams",2.6,.,42,6);`
0.99244673
`quant5=probmc("williams",.,.95,42,6);`
1.80654052
`quant1=probmc("williams",.,.99,42,6);`
2.49087829